**Создание сводной таблицы на основе нескольких листов**

Это глава из книги Билла Джелена [Гуру Excel расширяют горизонты: делайте невозможное с Microsoft Excel](http://baguzin.ru/wp/?p=12724).

Задача: у вас данных больше, чем может поместиться на одном листе, или данные по иным причинам распределены на нескольких листах (например, один месяц – один лист, рис. 1, или один отдел – один лист). Вы хотите создать сводную таблицу из данных, распределенных между несколькими листами. В старых версиях Excel функция консолидации работает, мягко выражаясь, странно (см., [Сводная таблица на основе нескольких листов](http://baguzin.ru/wp/?p=803)). Начиная с Excel 2013 функция консолидации значительно улучшена (см. [Сводная таблица на основе нескольких листов или диапазонов консолидации](http://baguzin.ru/wp/?p=10021)). Книга Джелена вышла в 2009 г., так что метод, предложенный в настоящей заметке, возможно, и не представляет значительной практической ценности. Однако, как я уже упоминал ранее, материалы Джелена методически интересны сами по себе, поэтому я счел полезным перевести и эту главу.



Рис. 1. Исходные данные расположены на пяти листах

Справочная информация: Fazza из Перта, Австралия, опубликовал замечательный фрагмент кода в 2008, который позволяет построить кеш сводной таблицы из нескольких листов или даже нескольких книг (больше информации о кеше можно найти в заметке [Excel 2013. Создание нескольких сводных таблиц на основе одного источника данных: один кеш или несколько?](http://baguzin.ru/wp/?p=9556)). Удивительно, но кеш сводной таблицы сохраняется вместе с книгой, так что, работая в Excel 2003, вы можете создать сводный отчет на основе более чем 65 536 строк.

Решение: предлагается создать SQL-оператор, чтобы собрать данные с нескольких листов в один массив. Вы фактически объединяете данные с нескольких листов в один набор записей. Далее вы открываете новую книгу и создаете сводную таблицу для внешнего набора данных – только что созданного набора записей. В результате получается чистая книга со сводной таблицей и кешем, хранящимся в ней, как бы, за кадром.

Вы пишете код, который создает массив из SQL-операторов. Полный код выглядит следующим образом (его также можно найти в модуле VBA в приложенном Excel-файле):

Sub BuildPivotCache()

 ' Adapted from http://www.mrexcel.com/forum/showthread.php?t=315768

 Dim i As Long

 Dim arSQL() As String

 Dim objPivotCache As PivotCache

 Dim objRS As Object

 Dim wbkNew As Workbook

 Dim wks As Worksheet

 With ActiveWorkbook

 ReDim arSQL(1 To .Worksheets.Count)

 For Each wks In .Worksheets

 i = i + 1

 arSQL(i) = "SELECT \* FROM [" & wks.Name & "$]"

 Next wks

 Set wks = Nothing

 Set objRS = CreateObject("ADODB.Recordset")

 objRS.Open Join$(arSQL, " UNION ALL "), Join$(Array("Provider=Microsoft.Jet.OLEDB.4.0; Data Source=", \_

 .FullName, ";Extended Properties=""Excel 8.0;"""), vbNullString)

 End With

 Set wbkNew = Workbooks.Add(Template:=xlWBATWorksheet)

 With wbkNew

 Set objPivotCache = .PivotCaches.Add(xlExternal)

 Set objPivotCache.Recordset = objRS

 Set objRS = Nothing

 With .Worksheets(1)

 objPivotCache.CreatePivotTable TableDestination:=.Range("A3")

 Set objPivotCache = Nothing

 Range("A3").Select

 End With

 End With

 Set wbkNew = Nothing

End Sub

Если активная книга содержит пять листов, массив может выглядеть как показано на рис. 2.



Рис. 2. Вы строите несколько SQL-запросов, чтобы собрать данные с каждого из пяти листов

Затем код создает новый набор записей на основе пяти запросов. Этот набор записей будет содержать все записи из всех таблиц. Где же этот набор записей сохраняется? Просто в памяти, как переменная объекта objRS. Позже, кода создается новая книга, этот набор записей используется в качестве источника для внешнего кеша сводной таблицы:

 Set objPivotCache = .PivotCaches.Add(xlExternal)

 Set objPivotCache.Recordset = objRS

В результаты работы кода вы получите новую книгу с пустой сводной (рис. 3). Как можно видеть, список полей сводной содержит список всех полей из таблицы, приведенной на рис. 1. Правда, на рис. 3 поля отсортированы по алфавиту.



Рис. 3. Хотя книга не содержит никаких видимых данных, в ней хранится кеш сводной таблицы

С этого момента, вы можете работать со сводной таблицей в обычном режиме (рис. 4).



Рис. 4. Сводная таблица

Если кеш сводной таблицы содержит меньше записей, чем строк на листе Excel, вы можете попробовать дважды щелкнуть на ячейке *Общий итог* (выделено на рис. 4). После этого на отдельный лист будут выведены данные, хранящиеся в кеше сводной таблицы (рис. 5)



Рис. 5. Данные, хранящиеся в кеше сводной таблицы

Подводный камень: в отличие от сводных таблиц, построенных из данных одного листа, эта сводная таблица не показывает никаких данных, пока вы разместите какое-либо поле в области ЗНАЧЕНИЯ. Не волнуйтесь, если вы разместили, например, поле *Region* в области СТРОКИ и ничего не произошло (регионы не отразились в строках таблицы). Как только вы добавите данные в область ЗНАЧЕНИЯ, сводная таблица проведет расчет, и регионы появятся.

Резюме: предложен код, который захватывает аналогичные данные из нескольких листов и представляет их в одной сводной таблице.

[Источник](http://www.mrexcel.com/forum/excel-questions/315768-creating-pivot-table-multiple-sheets.html). Решение было предложено Денисом Райтом (ник SydneyGeek), который, среди прочего, поддерживает [веб-сайт](http://www.datawright.com.au/excel_resources/excel.htm), посвященный Excel.