**ВПР для получения N-го вхождения и возврата из левого столбца**

Это глава из книги Билла Джелена [Гуру Excel расширяют горизонты: делайте невозможное с Microsoft Excel](http://baguzin.ru/wp/?p=12724).

Задача: ваши таблицы подстановки могут содержать несколько вхождений каждого ключевого поля. Вы хотели бы получить значения второго, третьего и т.д. вхождений.

Решение: ВПР не может решить эту проблему. Комбинация двух функций СМЕЩ и ПОИСКПОЗ могла бы это сделать, при условии, что таблица будет отсортирована по ключевому столбцу (подробнее см. [Билл Джелен. Всё о ВПР: от первого применения до экспертного уровня](http://baguzin.ru/wp/?p=12467)). Но если вам по каким-то соображения не удобно делать сортировку, можете воспользоваться пользовательской функцией VLOOKUPNTH (рис. 1). Вам нужно добавить эту функцию в проект VBA (если вы никогда не делали этого, см. [Сумма по цвету ячеек в Excel](http://baguzin.ru/wp/?p=317)). Чтобы получить доступ к коду в приложенном Excel-файле можно, например, кликнуть правой кнопкой мыши на ярлык листа и выбрать *Исходный текст*. Функция работает, как и ВПР, но вместо использования ЛОЖЬ/ИСТИНА в качестве четвертого аргумента, вы указываете, какое по порядку вхождение вы хотите получить для искомого значения.




Рис. 1. ВПР в столбце F, и VLOOKUPNTH в столбцах, начиная с G

Вот код этой функции

Function VLOOKUPNTH(lookup\_value, table\_array As Range, \_

col\_index\_num As Integer, nth\_value)

' Ищет N-е вхождение искомого значения

Dim nRow As Long

Dim nVal As Integer

Dim bFound As Boolean

VLOOKUPNTH = "Not Found"

With table\_array

For nRow = 1 To .Rows.Count

If .Cells(nRow, 1).Value = lookup\_value Then

nVal = nVal + 1

If nVal = nth\_value Then

VLOOKUPNTH = .Cells(nRow, col\_index\_num).Text

Exit Function

End If

End If

Next nRow

End With

End Function

Подробнее о функции. table\_array – это таблица подстановки, которая передается с листа Excel внутрь функции VBA. Функция VBA работает с диапазоном table\_array, начиная с 1-й строки и заканчивая последней (For nRow = 1 To .Rows.Count). Значение всегда ищется в первом столбце диапазона (If .Cells(nRow, 1).Value = lookup\_value Then). Если вхождение является N-м (If nVal = nth\_value Then) определяется значение для VLOOKUPNTH, которое берется из соответствующей строки и столбца таблицы подстановки (nRow, col\_index\_num). Если N-е вхождение не найдено возвращается ошибка (VLOOKUPNTH = "Not Found").

Дополнительные сведения: пользователи часто сокрушаются, что ВПР не может вернуть значение из столбца, расположенного слева от ключевого поля. Воспользуйтесь еще одной пользовательской функцией VLOOKNEW.

Function VLOOKNEW(lookup\_value, table\_array As Range, \_

col\_index\_num As Integer, CloseMatch As Boolean)

Dim nRow As Long

Dim nVal As Integer

Dim bFound As Boolean

VLOOKNEW = "Not Found"

If col\_index\_num > 0 Then

VLOOKNEW = Application.WorksheetFunction.VLookup(lookup\_value, \_

table\_array, col\_index\_num, CloseMatch)

Else

nRow = Application.WorksheetFunction.Match(lookup\_value, \_

table\_array.Resize(, 1), CloseMatch)

VLOOKNEW = table\_array(nRow, 1).Offset(0, col\_index\_num)

End If

End Function

VLOOKNEW аналогично ВПР, за исключением того, что вы можете использовать отрицательное значение для столбца *Порядковый номер* (рис. 2).




Рис. 2. VLOOKNEW возвращает значение, которое находится слева от ключевого поля

Резюме: пользовательские функции позволяют расширить возможности ВПР для поиска N-го вхождения и возврата значения из столбца, расположенного слева от ключевого поля.

[Источник](http://www.mrexcel.com/forum/excel-questions/112275-vlookup-2nd-value.html). Пост был номинирован Matt Hohbein. Спасибо Zack Barresse и Peter Moran.