**Проверка кода на наличие русских букв с помощью функции LAMBDA**

В декабре 2020 года Microsoft [анонсировал](https://www.microsoft.com/en-us/research/blog/lambda-the-ultimatae-excel-worksheet-function/) функцию LAMBDA, которая позволяет определять новые функции, написанные на языке формул Excel. На сегодня функция доступна только для Office 365. Функция LAMBDA поддерживает рекурсию, т.е. может вызывать сама себя. Это позволяет организовать циклы. Ранее я [опубликовал](https://baguzin.ru/wp/?p=24759) заметку, демонстрирующую мощь LAMBDA. А недавно возникла практическая задача, для решения которой LAMBDA подошла, как нельзя лучше! Я готовил к публикации конспект книги Алексея Васильева «Числовые расчеты в Excel». Код VBA, полученный с помощью программы распознавания текста, не работал. Я предполагал, что при обработке pdf файла некоторые символы были неверно распознаны. Например, где-то "с" английское, а где-то – русское. Для обычных формул Excel эта задача – не из простых. A LAMBDA справилась!



Рис. 1. Формула ЧРУС() на основе LAMBDA

#### Синтаксис функции LAMBDA

В общем виде синтаксис функции LAMBDA:



Рис. 2. Синтаксис функции LAMBDA

Последний аргумент функции LAMBDA – расчет (он же вычисление). Все предыдущие аргументы – параметры. Обязательный аргумент один. И это вычисление. Параметров может быть до 253.

Любопытной особенностью функции LAMBDA является отсутствие ссылок на ячейки в ее синтаксисе. Вместо них используются условные обозначения – параметры. Для того, чтобы можно было протестировать функцию в ячейке, разработчики добавили в синтаксис вызов функции

= LAMBDA([параметр1; параметр2; ...];вычисление) **(вызов функции)**

Вызов функции можно реализовать через передачу ей значений параметров:



Рис. 3. Тестирование функции LAMBDA

В нашем примере LAMBDA имеет два параметра – *х* (текст) и *k* (счетчик числа русских букв). В ячейке В2 они переданы после окончания кода функции в скобках – (А2;0). Поскольку в коде функции есть рекурсивная ссылка на неё саму, функцию ЧРУС не будет работать, пока не присвоить ей это имя.

Чтобы сделать это, пройдите *Формулы* –> *Диспетчер имен*, и введите ЧРУС в поле *Имя* в окне *Создание имени*.



Рис. 4. Присвоении функции имени

В поле *Диапазон* введите код функции:

=LAMBDA(x;k;

 ЕСЛИ(

 x="";

 k;

 ЕСЛИ(

 И(

 КОДСИМВ(ГОЛОВА(x))>=192;

 КОДСИМВ(ГОЛОВА(x))<=255

 );

 ЧРУС(ХВОСТ(x);k+1);

 ЧРУС(ХВОСТ(x);k)

 )

 )

)

Для упрощения восприятия я ввел две вспомогательных функции: ГОЛОВА(х) и ХВОСТ(Х):



Рис. 5. Вспомогательные функции

Эти функции я также определил с помощью имен. ГОЛОВА(х) возвращает первый символ текста, а ХВОСТ(х) – все остальные символы.

Разберем, как работает функция ЧРУС(x;k). Функция LAMBDA имеет три аргумента: два параметра…

=LAMBDA(x;k;

… и расчет…

 ЕСЛИ(

 x="";

 k;

 ЕСЛИ(

 И(

 КОДСИМВ(ГОЛОВА(x))>=192;

 КОДСИМВ(ГОЛОВА(x))<=255

 );

 ЧРУС(ХВОСТ(x);k+1);

 ЧРУС(ХВОСТ(x);k)

 )

 )

Суть расчета заключается в двух проверках и рекурсии. Первая проверка позволяет выйти из цикла, когда все символы проверяемого текста *x* просмотрены:

 ЕСЛИ(

 x="";

 k;

Если просматриваемый текст пустой…

 x="";

вернуть…

 k;

… если же не пустой приступить ко второй проверке…

 ЕСЛИ(

 И(

 КОДСИМВ(ГОЛОВА(x))>=192;

 КОДСИМВ(ГОЛОВА(x))<=255

 );

Если первый символ текста *х* (именно он возвращается функцией ГОЛОВА) принадлежит русскому алфавиту, т.е., его код лежит в диапазоне от 192 до 255, то…

 ЧРУС(ХВОСТ(x);k+1);

… находясь внутри функции ЧРУС запустить функцию повторно (рекурсивно) с параметрами х = ХВОСТ(x) и k = k + 1. Т.е., повторно запускаемая функция ЧРУС принимает не весь текст х, а его часть – без первого символа, который только что был просмотрен и изучен, а параметр k (счетчик) увеличен на единицу, так как символ оказался русским…

Если же символ **не** принадлежит русскому алфавиту…

 ЧРУС(ХВОСТ(x);k)

… запустить функцию повторно (рекурсивно) с параметрами х = ХВОСТ(x) и k = k. Т.е., тоже передать функции не весь текст х, а его часть – без первого символа, а счетчик k не менять, так как символ был не русским…

В итоги для текста в ячейке А2 функция ЧРУС() вернет значение 9 (см. рис. 3). И действительно, в тексте "Sub Дихотомия()" девять русских символов. Для ячейки А2 этот вывод тривиален, а вот для ячейки А15 мы ожидали значение 0, так как это код VBA, но вернулось значение 1. Следовательно надо заменить на английскую одну из букв, которые одинаково выглядят в обоих языках. Русской оказалась первая буква строки – "а".

Перед запуском функции ЧРУС(), я дополнительно исключил из проверки строки с комментариями, начинающиеся с апострофа, а также исключил возможный пробел в начале строки, добавив функцию СЖПРОБЕЛЫ():

=ЕСЛИ(ЛЕВСИМВ(СЖПРОБЕЛЫ(A2))="'";"";ЧРУС(A2;0))